* Reference: Chapter 13 of
* Jeffrey M. Wooldridge, Introductory Econometrics: A Modern Approach,
* South-Western College Publishing, 2000.
SAMPLE 1 53
READ (CRIME3.shd) district year crime clrprc1 clrprc2 d78a avgclr &
  lcrime clcrime cavgclr cclrprc1 cclrprc2 &
  dist78 year78 crime78 clrp178 clrp278 d78b avgclr78 &
  lcrime78 clcri78 cavgc78 cclrp178 cclrp278 
* Data validation check
IF (year.ne.72)
  STOP
IF (year78.ne.78)
  STOP

SET MISSVALU=-999
SET SKIPMISS
SET NOWARNMISS 

* Example 13.6
* Differencing across the 2 years. 
GENR dlcrime=log(crime78)-log(crime)
GENR dclear1=clrp178-clrprc1
GENR dclear2=clrp278-clrprc2
* Equation (13.22), p. 425.
OLS dlcrime dclear1 dclear2 / LOGLIN
* For an interpretation of the coefficients when the dependent
* variable is log-transformed and the explanatory variable is
* in levels see Example 3.2, pp. 74-75.
* For an interpretation of the coefficients for a distributed
* lag model see Section 10.2, pp. 313-315.

* The estimated coefficient on the variable dclear2 is -0.0132.
* This suggests that a one unit increase in the clear-up 
* percentage two years ago (assuming this is a temporary change not 
* sustained in the next period) leads to a decline in log(crime) by 
* 0.0132. This measures a proportionate change in the crime rate. 
* The percentage drop in the crime rate in response to a one unit 
* increase in the clear-up percentage two years ago is 
* 100*0.0132 = 1.32 %.
* (For a discussion of proportionate changes versus percentage
* changes Appendix A.3, pp. 648-650).

* Assuming a permanent change in the clear-up percentage 
* (the percentage of crimes that lead to a conviction),
* estimate the long-run percentage change in the crime rate
* for a one percentage point increase in the clear-up rate.
TEST 100*(dclear1+dclear2)

* Now re-scale the dependent variable so that the estimated
* coefficients now have an interpretation as percentage changes
* rather than proportionate changes.
GENR dlcrime=100*dlcrime
OLS dlcrime dclear1 dclear2 / LOGLIN
TEST dclear1+dclear2
STOP