* Chapter 15.4 - The Seemingly Unrelated Regression Model.
* W.H. Greene, Econometric Analysis, Fourth Edition, 2000.
SAMPLE 1 20 
READ (grunfeld.shd) YEAR FIRM I1 F1 C1 / NOREWIND SKIPLINE=1
READ (grunfeld.shd) YEAR FIRM I2 F2 C2 / NOREWIND     
READ (grunfeld.shd) YEAR FIRM I3 F3 C3 / NOREWIND     
READ (grunfeld.shd) YEAR FIRM I4 F4 C4 / NOREWIND     
READ (grunfeld.shd) YEAR FIRM I5 F5 C5 / NOREWIND     

* Example 15.9 
* Generate a constant to allow hypothesis testing on the
* intercept coefficients.
GENR CONST=1
* Model Estimation - Results in Table 15.6, p. 619   
*   - The ITERATION 1 SIGMA listed on the SHAZAM output is the
*     Residual Covariance Matrix printed in Table 15.6.
*   - The BREUSCH-PAGAN LM TEST is computed using formula (15-46)
*     on p. 621. The test statistic is 29.060 (the number 29.046
*     reported at top of p. 622 appears to be a typo).
SYSTEM 5 / DN NOCONSTANT
OLS I1 F1 C1 CONST
OLS I2 F2 C2 CONST
OLS I3 F3 C3 CONST 
OLS I4 F4 C4 CONST
OLS I5 F5 C5 CONST
END
* Test for equal coefficients across equations (cross-sections).
TEST 
 TEST F1=F2
 TEST F1=F3
 TEST F1=F4
 TEST F1=F5
 TEST C1=C2
 TEST C1=C3
 TEST C1=C4
 TEST C1=C5
 TEST CONST:1=CONST:2
 TEST CONST:1=CONST:3
 TEST CONST:1=CONST:4
 TEST CONST:1=CONST:5
END
* The TEST commands report a WALD CHI-SQUARE STATISTIC that is saved
* in the temporary variable $CHI.
* Calculate the F-statistic reported on p. 621.
GEN1 F=$CHI/$DF1
PRINT F

* Iterated FGLS - p. 622
* The ITER= option sets the maximum number of iterations.
SYSTEM 5 / DN ITER=20 
OLS I1 F1 C1 
OLS I2 F2 C2 
OLS I3 F3 C3 
OLS I4 F4 C4 
OLS I5 F5 C5 
END
* The estimation results are not identical to the results
* reported in Table 15.8 due to differences in the numerical
* estimation method.
STOP