*   R. Carter Hill, William E. Griffiths and Guay C. Lim,  
*   Principles of Econometrics, Third Edition, Wiley, 2008.

* Chapter 15  Seemingly Unrelated Regressions

SAMPLE 1 20
READ (grunfeld2.shd) INV1 V1 K1 INV2 V2 K2

* Separate OLS regressions - Table 15.1, page 386
OLS INV1 V1 K1
GEN1 S2GE=$SIG2
GEN1 DF1=$DF

OLS INV2 V2 K2
GEN1 S2WE=$SIG2
GEN1 DF2=$DF

* Goldfeld-Quandt test for heteroskedasticity
GEN1 F=S2GE/S2WE
* Get a p-value
DISTRIB F / TYPE=F DF1=DF1 DF2=DF2
GEN1 pvalue=1-$CDF
PRINT F pvalue
* The pvalue is less than 0.005 to give evidence to reject
* the null hypothesis of homoskedastic errors at any 
* usual significance level.

* Pool the data
MATRIX INV=(INV1'|INV2')'
MATRIX V=(V1'|V2')'
MATRIX K=(K1'|K2')'

SAMPLE 1 40
* Estimate a pooled model
OLS INV V K 
* The DIAGNOS / CHOWONE=  command calculates and reports the
* Goldfeld-Quandt test statistic as reported above and the
* Chow test statistic for the same coefficients for the two firms.
DIAGNOS / CHOWONE=20

* Generate a dummy variable = 1 for Westinghouse
GENR OBS=TIME(0)
GENR D=(OBS.GT.20)
* Generate interaction variables
GENR DV=D*V
GENR DK=D*K

* Estimate a dummy variable model - Table 15.2, page 387.
OLS INV D V DV K DK
* Chow test for the same investment functions for the two firms.
* This is the same test reported above following estimaton of
* the pooled model.
TEST
 TEST D=0
 TEST DV=0
 TEST DK=0
END

* Seemingly Unrelated Regression 
SAMPLE 1 20
* Generate a constant term -- this is required so that hypothesis
* testing on the intercept can be considered.
GENR ONE=1
* Model estimation with the SYSTEM command - Table 15.3, p. 388.
SYSTEM 2 / NOCONSTANT
OLS INV1 V1 K1 ONE
OLS INV2 V2 K2 ONE
END
* The estimation output reports the test statistic:
*    BREUSCH-PAGAN LM TEST FOR DIAGONAL COVARIANCE MATRIX
* This is the LM test statistic discussed in Chapter 15.3.1, pp. 389-90.
* Testing cross-equation restrictions - Chapter 15.3.2, pp. 390-1.
* On the TEST command, the variable names represent the coefficients.
TEST
 TEST ONE:1=ONE:2
 TEST V1=V2
 TEST K1=K2
END 
STOP