*   R. Carter Hill, William E. Griffiths and Guay C. Lim,  
*   Principles of Econometrics, Third Edition, Wiley, 2008.

* Chapters 5, 6 - The Multiple Regression Model

SAMPLE 1 75
* Observations on Sales Revenue, Price and Advertising
* for a sample of 75 cities
READ (andy.shd) SALES PRICE ADVERT

* Summary statistics (Table 5.1, p. 109)
STAT SALES PRICE ADVERT

* Least squares estimation (Table 5.2, p. 112).
* On the OLS output:
*    - the estimate of the error variance is reported as:
*      VARIANCE OF THE ESTIMATE-SIGMA**2  (p. 114).
* On the OLS command:
*    - the PCOV option reports the estimated variance-covariance
*      matrix of the parameter estimators (Table 5.3, p. 117).
*    - the ANOVA option reports the analysis of variance table and 
*      the F-test for overall significance (top of p. 140).

OLS SALES PRICE ADVERT / PCOV ANOVA

* Interval estimation (p. 119).
CONFID PRICE ADVERT

* Testing advertising effectiveness (pp. 123-4).
* Note: The TEST command reports a test statistic and 
* p-value for a 2-sided test. This p-value can be transformed
* to a p-value for a one-sided test.
TEST ADVERT=1

* Chapter 6.3  An extended model (Equation 6.11, p. 141)
GENR ADV2=ADVERT**2
OLS SALES PRICE ADVERT ADV2

* Chapter 6.4  Testing some economic hypotheses
* The TEST command uses the results from the previous OLS
* estimation command. On the TEST command the variable names
* represent the regression coefficients.
* A joint test for the significance of advertising (p. 142).
TEST
 TEST ADVERT=0
 TEST ADV2=0
END
* A test for the optimal level of advertising (p. 143).
TEST ADVERT+3.8*ADV2=1

* A joint test (Chapter 6.4.3, p. 145).
TEST
 TEST ADVERT+3.8*ADV2=1
 TEST CONSTANT+6*PRICE+1.9*ADVERT+3.61*ADV2=80
END

STOP