*   R. Carter Hill, William E. Griffiths and Guay C. Lim,  
*   Principles of Econometrics, Fourth Edition, Wiley, 2011.

* Chapter 15.7  Sets of Regression Equations

READ (grunfeld2.dat) / names

* The firm identifiers are:
*  i = 1 General Electric; i = 2 Westinghouse

* Pooled least squares - Table 15.11, page 564.
OLS inv v k
* The DIAGNOS / CHOWONE=  command calculates and reports the
* Goldfeld-Quandt test statistic as reported above and the
* Chow test statistic for the same coefficients for the two firms.
* The Chow test is reported in Equation (15.45) page 565.
* The Goldfeld-Quandt test is reported on pages 565-6.
DIAGNOS / CHOWONE=20

* Generate a dummy variable = 1 for Westinghouse
GENR D=(I.EQ.2)
* Generate interaction variables
GENR DV=D*V
GENR DK=D*K

* Estimate a dummy variable model - Table 15.12, page 565.
OLS INV D V DV K DK
* Chow test for the same investment functions for the two firms.
* This is the same test reported above following estimaton of
* the pooled model.
TEST
 TEST D=0
 TEST DV=0
 TEST DK=0
END

* Separate least squares regressions - Table 15.13, page 566
SET NOWARNSKIP
*  General Electric
SKIPIF (I.NE.1)
OLS inv v k
GEN1 S2GE=$SIG2
GEN1 DF1=$DF
DELETE SKIP$

*  Westinghouse
SKIPIF (I.NE.2)
OLS inv v k
GEN1 S2WE=$SIG2
GEN1 DF2=$DF
DELETE SKIP$

* Goldfeld-Quandt test for heteroskedasticity
GEN1 F=S2GE/S2WE
* Get a p-value
DISTRIB F / TYPE=F DF1=DF1 DF2=DF2
GEN1 pvalue=1-$CDF
PRINT F pvalue
* The pvalue is less than 0.005 to give evidence to reject
* the null hypothesis of homoskedastic errors at any 
* usual significance level.
STOP